Supplemental materials for “Totally symmetric sets in the general linear group”

Noah Caplinger and Nick Salter

Run this first - this constructs the representation.

zeta= Exp[I*Pi/3];
P12 = {{0,-1},{1,0}}; 
P23 = P12;
P34 = {{0,-zeta^2},{-zeta,0}};
Q34 = {{0,-zeta},{-zeta^2,0}};
P45 = (I/Sqrt[3]) {{Sqrt[2],1},{1,-Sqrt[2]}};

T1 = ArrayFlatten[{{0,P12},{P12,0}}];
T2 = ArrayFlatten[{{P23,-P23},{0,-P23}}]; 
T3 = ArrayFlatten[{{P34,0},{0,Q34}}];
T4 = ArrayFlatten[{{P45,0},{0,P45}}];
Z = -1*IdentityMatrix[4];

Lemma A.2: Verifying that this is a representation of

MatrixPower[T1,2]==Z
MatrixPower[T2,2]==Z
MatrixPower[T3,2]==Z
MatrixPower[T4,2]==Z

MatrixPower[T1.T2,3] ==Z
MatrixPower[T2.T3,3] ==Z//Simplify
MatrixPower[T3.T4,3] ==Z//Simplify

T1.T3 == Z.T3.T1
T1.T4 == Z.T4.T1
T2.T4 == Z.T4.T2

Example A.5

Step 1: constructing  via a projection formula

To compute , we utilize the projection formula for projecting a -representation V onto the -isotypic component:

We apply this in the case  embedded in as the stabilizer of 1, , and . The character for  appears in [HH92, p. 43] as . There are three pairs of conjugacy classes on which  is nonzero: the conjugacy classes above . These take values , respectively. Given one such conjugacy class , the associated conjugacy class  is given by . Thus  (as indeed we already observed), and so in the projection formula since , there is an equality

.

It follows that we can simplify the projection formula by only considering a sum over one of each pair of conjugacy classes and weighting by a factor of . This leads to the projection formula given below; we must first enumerate the elements of the relevant conjugacy classes. In the expressions below there is a scattering of negative signs; these are put in place to ensure that the elements in question lie in the correct conjugacy class, as can be checked via traces.

T12 = T1; T23 = T2; T34 = T3;T45=T4;

T13 = -T23.T12.T23; T14 = -T34.T13.T34; T24 = -T23.T34.T23;
T15 = -T45.T14.T45;T25 = -T12.T15.T12;T35 = -T23.T25.T23;

T234 = T23.T34; T235 = -T23.T35; T245 = -T24.T45;T345 = T34.T45;

T2345= T23.T34.T45; T2354=-T45.T2345.T45; T2435 = -T34.T2345.T34; T2453 = -T35.T2435.T35;T2534 = -T45.T2435.T45;T2543 = -T34.T2534.T34;

We can now define the projection operator. For the conjugacy class above (234) we have chosen, the character value is , and for our conjugacy class above  it is .

P =(2/48)*( 4*IdentityMatrix[4]+2*(T234+Inverse[T234]+T245+Inverse[T245]+ T235+Inverse[T235]+T345 + Inverse[T345])-2*Sqrt[2]*(T2345 + T2354 + T2435 + T2453 + T2534 + T2543));

Verifying that P is a projection operator:

P.P==P//Simplify

The kernel of P is therefore the associate representation , i.e. the space  we seek to describe.

Transpose[NullSpace[P]]//MatrixForm//Simplify

Step 2: constructing

To construct , we follow the procedure outlined in the text: we let  be the change-of-basis matrix, set  for  the diagonal matrix with entries , and then conjugate  by the elements  to obtain .

M = Transpose[ArrayFlatten[{{Transpose[ArrayFlatten[{{IdentityMatrix[2]},{0},{0}}]]},{NullSpace[P]}}]];
A1  = M.DiagonalMatrix[{λ,λ,μ,μ}].Inverse[M];
A2 = T12.A1.Inverse[T12];
A3 = T13.A1.Inverse[T13];
A4 = T14.A1.Inverse[T14];
A5 = T15.A1.Inverse[T15];

Lemma A.6

A4 = {{zeta,(zeta^(-1)-zeta)/2},{0,zeta^(-1)}};
A6 = {{(zeta^(-1)+zeta)/2,(zeta-zeta^(-1))/2},{(zeta-zeta^(-1))/2,(zeta^(-1)+zeta)/2}};
Y={{c+d,c-d},{d-c,-c-d}};
A6.Y.A4-A4.Y//Simplify//MatrixForm

Solve[{(1/2) (c-2 I (Sqrt[3]) c+I (2 I+(Sqrt[3])) d)==0,-(1/4) (((-1))^(1/3)) (14 c+d+I (Sqrt[3]) d)==0},{c,d}]

Lemma A.7

A4 = DiagonalMatrix[{zeta,zeta^(-1)}];
M = {{a,b},{c,d}};
A5 = M.A4.Inverse[M];
Y = {{0,q},{p,0}};
A4.Y.A5-A5.Y//Simplify//MatrixForm

Solve[(2 (((-1))^(2/3)) b c+(-1+(((-1))^(1/3))) a d) q==0,d]

Lemma A.10

P45.Q34 -P34.P45//Simplify//MatrixForm

Lemma 11.3

First we initialize the elements

mu = (-1 + 2 Sqrt[2]*I)/3; lambda = mu^(-1);
X1 = IdentityMatrix[2]; X2 = {{-mu - 2/3,mu+1/3},{0,mu}};X3 = {{mu,0},{mu+1/3,-mu-2/3}}; X4 = {{-1/3,-mu-1/3},{-mu-1/3,-1/3}};

Next we construct   and Q,  recalling the constants b and  involved in their definition.

alpha = (mu-lambda)/2; b = alpha^(-1)(1-mu);
P = {{1,b},{2,-1}}; Q = {{lambda,alpha + mu*b},{2 lambda, -lambda}};

To check total symmetry, we verify the following:

P.X1==X2.Q//Simplify
P.X2==X1.Q//Simplify
P.X3 == X3.Q//Simplify
P.X4 == X4.Q//Simplify

Proposition 12.1

Don’t forget to ensure that the  are defined correctly (as in Example A.3).

a1 = A1/.λ->1/.μ->-1;
a2 = A2/.λ->1/.μ->-1;
a1//MatrixForm//Simplify
a2//MatrixForm//Simplify

MatrixPower[a1.a2,3]//Simplify//MatrixForm